Hello skalyniuk,

I've investigated the issue and found that there are no built-in properties or methods to specify text-wrapping on card view caption area.

Instead, you could use DrawFilter:
    Draw Filter
    https://es.infragistics.com/help/winforms/win-draw-filter

In GetPhasesToFilter method, you could check whether the UI element is CardCaptionUIElement and if it is the case, you could return DrawPhase.BeforeDrawForeground.
And in DrawElement method, set WrapText as True when the CardCaptionUIElement has a child which is TextUIElement.

Here is a code snippet:

    UltraGrid1.DrawFilter = New MyDrawFilter()

    ....

    Imports Infragistics.Win
    Imports Infragistics.Win.UltraWinGrid

    Public Class MyDrawFilter
        Implements IUIElementDrawFilter

        Private Function IUIElementDrawFilter_DrawElement(drawPhase As DrawPhase, ByRef drawParams As UIElementDrawParams) As Boolean Implements IUIElementDrawFilter.DrawElement
            Dim cardCaptionUIElement = TryCast(drawParams.Element, CardCaptionUIElement)
            If cardCaptionUIElement IsNot Nothing AndAlso cardCaptionUIElement.ChildElements.Count > 0 Then
                Dim textElement = TryCast(cardCaptionUIElement.ChildElements(0), TextUIElement)
                If textElement IsNot Nothing Then
                    textElement.WrapText = True
                End If
            End If

            Return False
        End Function

        Private Function IUIElementDrawFilter_GetPhasesToFilter(ByRef drawParams As UIElementDrawParams) As DrawPhase Implements IUIElementDrawFilter.GetPhasesToFilter
            If TypeOf drawParams.Element Is CardCaptionUIElement Then
                Return DrawPhase.BeforeDrawForeground
            End If

            Return DrawPhase.None
        End Function
    End Class

I hope this will help you.

Best Regards,

Noriko I.
Developer Support Engineer
Infragistics, Inc.